/* REXX *** */        
/* report on USS initiator usage */        
cvt = C2D(storage(10,4))        
asvt = C2D(STORAGE(D2X(cvt+556),4))        
eye = STORAGE(D2X(asvt+512),4)        
IF eye ^= 'ASVT' then DO        
   SAY 'Eye catcher for ASVT at 'D2X(asvt+512)' missing'        
   EXIT 8        
   END        
maxu = C2D(STORAGE(D2X(asvt+516),4))        
base = asvt+524        
Say 'USS Initiator Activity'        
Say 'Jobname  Asid Jobid    Userid'        
Say '-------- ---- -------- -------'        
Numeric Digits 10        
act = 0        
inact = 0        
DO i = 1 to maxu        
    ascb = C2X(STORAGE(D2X(base+4*i),4))        
    /* check active asids */        
    IF LEFT(ascb,1) ^= '8' then DO        
       ascbx = X2D(ascb)        
       nm = C2X(STORAGE(D2X(ascbx+176),4))        
       IF nm ^= '00000000' then  DO           
         init = STORAGE(nm,8)        
         nm = C2X(STORAGE(D2X(ascbx+172),4))        
         /* examine BPXAS initiators with work */        
         IF init = 'BPXAS' then ,        
         If nm ^= '00000000'            
         then DO        
           name = STORAGE(nm,8)           
           asid = C2X(STORAGE(D2X(ascbx+36),2))        
           assb = C2D(STORAGE(D2X(ascbx+336),4))        
           jsab = C2D(STORAGE(D2X(assb+168),4))         
           jbid  = STORAGE(D2X(jsab+20),8)        
           usid  = STORAGE(D2X(jsab+44),8)        
           Say name' 'asid' 'jbid' 'usid                      
           act = act + 1        
           END        
        else  inact = inact + 1        
        END        
       END        
    END i        
Say '** Active = 'act' Inactive = 'inact' Total = 'inact+act' **'        
EXIT 0